8f34c2760d
project:cfg:BoardConfig_IPC: Added fastboot BoardConfig file and firmware post-scripts, distinguishing between the BoardConfigs for Luckfox Pico Pro and Luckfox Pico Max. project:app: Added fastboot_client and rk_smart_door for quick boot applications; updated rkipc app to adapt to the latest media library. media:samples: Added more usage examples. media:rockit: Fixed bugs; removed support for retrieving data frames from VPSS. media:isp: Updated rkaiq library and related tools to support connection to RKISP_Tuner. sysdrv:Makefile: Added support for compiling drv_ko on Luckfox Pico Ultra W using Ubuntu; added support for custom root filesystem. sysdrv:tools:board: Updated Buildroot optional mirror sources, updated some software versions, and stored device tree files and configuration files that undergo multiple modifications for U-Boot and kernel separately. sysdrv:source:mcu: Used RISC-V MCU SDK with RT-Thread system, mainly for initializing camera AE during quick boot. sysdrv:source:uboot: Added support for fastboot; added high baud rate DDR bin for serial firmware upgrades. sysdrv:source:kernel: Upgraded to version 5.10.160; increased NPU frequency for RV1106G3; added support for fastboot. Signed-off-by: luckfox-eng29 <eng29@luckfox.com>
196 lines
2.6 KiB
ArmAsm
196 lines
2.6 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-or-later */
|
|
/*
|
|
* atomic64_t for 386/486
|
|
*
|
|
* Copyright © 2010 Luca Barbieri
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/alternative.h>
|
|
|
|
/* if you want SMP support, implement these with real spinlocks */
|
|
.macro IRQ_SAVE reg
|
|
pushfl
|
|
cli
|
|
.endm
|
|
|
|
.macro IRQ_RESTORE reg
|
|
popfl
|
|
.endm
|
|
|
|
#define BEGIN_IRQ_SAVE(op) \
|
|
.macro endp; \
|
|
SYM_FUNC_END(atomic64_##op##_386); \
|
|
.purgem endp; \
|
|
.endm; \
|
|
SYM_FUNC_START(atomic64_##op##_386); \
|
|
IRQ_SAVE v;
|
|
|
|
#define ENDP endp
|
|
|
|
#define RET_IRQ_RESTORE \
|
|
IRQ_RESTORE v; \
|
|
RET
|
|
|
|
#define v %ecx
|
|
BEGIN_IRQ_SAVE(read)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(set)
|
|
movl %ebx, (v)
|
|
movl %ecx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(xchg)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
movl %ebx, (v)
|
|
movl %ecx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %ecx
|
|
BEGIN_IRQ_SAVE(add)
|
|
addl %eax, (v)
|
|
adcl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %ecx
|
|
BEGIN_IRQ_SAVE(add_return)
|
|
addl (v), %eax
|
|
adcl 4(v), %edx
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %ecx
|
|
BEGIN_IRQ_SAVE(sub)
|
|
subl %eax, (v)
|
|
sbbl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %ecx
|
|
BEGIN_IRQ_SAVE(sub_return)
|
|
negl %edx
|
|
negl %eax
|
|
sbbl $0, %edx
|
|
addl (v), %eax
|
|
adcl 4(v), %edx
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(inc)
|
|
addl $1, (v)
|
|
adcl $0, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(inc_return)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
addl $1, %eax
|
|
adcl $0, %edx
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(dec)
|
|
subl $1, (v)
|
|
sbbl $0, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(dec_return)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
subl $1, %eax
|
|
sbbl $0, %edx
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(add_unless)
|
|
addl %eax, %ecx
|
|
adcl %edx, %edi
|
|
addl (v), %eax
|
|
adcl 4(v), %edx
|
|
cmpl %eax, %ecx
|
|
je 3f
|
|
1:
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
movl $1, %eax
|
|
2:
|
|
RET_IRQ_RESTORE
|
|
3:
|
|
cmpl %edx, %edi
|
|
jne 1b
|
|
xorl %eax, %eax
|
|
jmp 2b
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(inc_not_zero)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
testl %eax, %eax
|
|
je 3f
|
|
1:
|
|
addl $1, %eax
|
|
adcl $0, %edx
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
movl $1, %eax
|
|
2:
|
|
RET_IRQ_RESTORE
|
|
3:
|
|
testl %edx, %edx
|
|
jne 1b
|
|
jmp 2b
|
|
ENDP
|
|
#undef v
|
|
|
|
#define v %esi
|
|
BEGIN_IRQ_SAVE(dec_if_positive)
|
|
movl (v), %eax
|
|
movl 4(v), %edx
|
|
subl $1, %eax
|
|
sbbl $0, %edx
|
|
js 1f
|
|
movl %eax, (v)
|
|
movl %edx, 4(v)
|
|
1:
|
|
RET_IRQ_RESTORE
|
|
ENDP
|
|
#undef v
|