8f34c2760d
project:cfg:BoardConfig_IPC: Added fastboot BoardConfig file and firmware post-scripts, distinguishing between the BoardConfigs for Luckfox Pico Pro and Luckfox Pico Max. project:app: Added fastboot_client and rk_smart_door for quick boot applications; updated rkipc app to adapt to the latest media library. media:samples: Added more usage examples. media:rockit: Fixed bugs; removed support for retrieving data frames from VPSS. media:isp: Updated rkaiq library and related tools to support connection to RKISP_Tuner. sysdrv:Makefile: Added support for compiling drv_ko on Luckfox Pico Ultra W using Ubuntu; added support for custom root filesystem. sysdrv:tools:board: Updated Buildroot optional mirror sources, updated some software versions, and stored device tree files and configuration files that undergo multiple modifications for U-Boot and kernel separately. sysdrv:source:mcu: Used RISC-V MCU SDK with RT-Thread system, mainly for initializing camera AE during quick boot. sysdrv:source:uboot: Added support for fastboot; added high baud rate DDR bin for serial firmware upgrades. sysdrv:source:kernel: Upgraded to version 5.10.160; increased NPU frequency for RV1106G3; added support for fastboot. Signed-off-by: luckfox-eng29 <eng29@luckfox.com>
180 lines
4.2 KiB
ArmAsm
180 lines
4.2 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*---------------------------------------------------------------------------+
|
|
| mul_Xsig.S |
|
|
| |
|
|
| Multiply a 12 byte fixed point number by another fixed point number. |
|
|
| |
|
|
| Copyright (C) 1992,1994,1995 |
|
|
| W. Metzenthen, 22 Parker St, Ormond, Vic 3163, |
|
|
| Australia. E-mail billm@jacobi.maths.monash.edu.au |
|
|
| |
|
|
| Call from C as: |
|
|
| void mul32_Xsig(Xsig *x, unsigned b) |
|
|
| |
|
|
| void mul64_Xsig(Xsig *x, unsigned long long *b) |
|
|
| |
|
|
| void mul_Xsig_Xsig(Xsig *x, unsigned *b) |
|
|
| |
|
|
| The result is neither rounded nor normalized, and the ls bit or so may |
|
|
| be wrong. |
|
|
| |
|
|
+---------------------------------------------------------------------------*/
|
|
.file "mul_Xsig.S"
|
|
|
|
|
|
#include "fpu_emu.h"
|
|
|
|
.text
|
|
SYM_FUNC_START(mul32_Xsig)
|
|
pushl %ebp
|
|
movl %esp,%ebp
|
|
subl $16,%esp
|
|
pushl %esi
|
|
|
|
movl PARAM1,%esi
|
|
movl PARAM2,%ecx
|
|
|
|
xor %eax,%eax
|
|
movl %eax,-4(%ebp)
|
|
movl %eax,-8(%ebp)
|
|
|
|
movl (%esi),%eax /* lsl of Xsig */
|
|
mull %ecx /* msl of b */
|
|
movl %edx,-12(%ebp)
|
|
|
|
movl 4(%esi),%eax /* midl of Xsig */
|
|
mull %ecx /* msl of b */
|
|
addl %eax,-12(%ebp)
|
|
adcl %edx,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull %ecx /* msl of b */
|
|
addl %eax,-8(%ebp)
|
|
adcl %edx,-4(%ebp)
|
|
|
|
movl -12(%ebp),%eax
|
|
movl %eax,(%esi)
|
|
movl -8(%ebp),%eax
|
|
movl %eax,4(%esi)
|
|
movl -4(%ebp),%eax
|
|
movl %eax,8(%esi)
|
|
|
|
popl %esi
|
|
leave
|
|
RET
|
|
SYM_FUNC_END(mul32_Xsig)
|
|
|
|
|
|
SYM_FUNC_START(mul64_Xsig)
|
|
pushl %ebp
|
|
movl %esp,%ebp
|
|
subl $16,%esp
|
|
pushl %esi
|
|
|
|
movl PARAM1,%esi
|
|
movl PARAM2,%ecx
|
|
|
|
xor %eax,%eax
|
|
movl %eax,-4(%ebp)
|
|
movl %eax,-8(%ebp)
|
|
|
|
movl (%esi),%eax /* lsl of Xsig */
|
|
mull 4(%ecx) /* msl of b */
|
|
movl %edx,-12(%ebp)
|
|
|
|
movl 4(%esi),%eax /* midl of Xsig */
|
|
mull (%ecx) /* lsl of b */
|
|
addl %edx,-12(%ebp)
|
|
adcl $0,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 4(%esi),%eax /* midl of Xsig */
|
|
mull 4(%ecx) /* msl of b */
|
|
addl %eax,-12(%ebp)
|
|
adcl %edx,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull (%ecx) /* lsl of b */
|
|
addl %eax,-12(%ebp)
|
|
adcl %edx,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull 4(%ecx) /* msl of b */
|
|
addl %eax,-8(%ebp)
|
|
adcl %edx,-4(%ebp)
|
|
|
|
movl -12(%ebp),%eax
|
|
movl %eax,(%esi)
|
|
movl -8(%ebp),%eax
|
|
movl %eax,4(%esi)
|
|
movl -4(%ebp),%eax
|
|
movl %eax,8(%esi)
|
|
|
|
popl %esi
|
|
leave
|
|
RET
|
|
SYM_FUNC_END(mul64_Xsig)
|
|
|
|
|
|
|
|
SYM_FUNC_START(mul_Xsig_Xsig)
|
|
pushl %ebp
|
|
movl %esp,%ebp
|
|
subl $16,%esp
|
|
pushl %esi
|
|
|
|
movl PARAM1,%esi
|
|
movl PARAM2,%ecx
|
|
|
|
xor %eax,%eax
|
|
movl %eax,-4(%ebp)
|
|
movl %eax,-8(%ebp)
|
|
|
|
movl (%esi),%eax /* lsl of Xsig */
|
|
mull 8(%ecx) /* msl of b */
|
|
movl %edx,-12(%ebp)
|
|
|
|
movl 4(%esi),%eax /* midl of Xsig */
|
|
mull 4(%ecx) /* midl of b */
|
|
addl %edx,-12(%ebp)
|
|
adcl $0,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull (%ecx) /* lsl of b */
|
|
addl %edx,-12(%ebp)
|
|
adcl $0,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 4(%esi),%eax /* midl of Xsig */
|
|
mull 8(%ecx) /* msl of b */
|
|
addl %eax,-12(%ebp)
|
|
adcl %edx,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull 4(%ecx) /* midl of b */
|
|
addl %eax,-12(%ebp)
|
|
adcl %edx,-8(%ebp)
|
|
adcl $0,-4(%ebp)
|
|
|
|
movl 8(%esi),%eax /* msl of Xsig */
|
|
mull 8(%ecx) /* msl of b */
|
|
addl %eax,-8(%ebp)
|
|
adcl %edx,-4(%ebp)
|
|
|
|
movl -12(%ebp),%edx
|
|
movl %edx,(%esi)
|
|
movl -8(%ebp),%edx
|
|
movl %edx,4(%esi)
|
|
movl -4(%ebp),%edx
|
|
movl %edx,8(%esi)
|
|
|
|
popl %esi
|
|
leave
|
|
RET
|
|
SYM_FUNC_END(mul_Xsig_Xsig)
|