8f34c2760d
project:cfg:BoardConfig_IPC: Added fastboot BoardConfig file and firmware post-scripts, distinguishing between the BoardConfigs for Luckfox Pico Pro and Luckfox Pico Max. project:app: Added fastboot_client and rk_smart_door for quick boot applications; updated rkipc app to adapt to the latest media library. media:samples: Added more usage examples. media:rockit: Fixed bugs; removed support for retrieving data frames from VPSS. media:isp: Updated rkaiq library and related tools to support connection to RKISP_Tuner. sysdrv:Makefile: Added support for compiling drv_ko on Luckfox Pico Ultra W using Ubuntu; added support for custom root filesystem. sysdrv:tools:board: Updated Buildroot optional mirror sources, updated some software versions, and stored device tree files and configuration files that undergo multiple modifications for U-Boot and kernel separately. sysdrv:source:mcu: Used RISC-V MCU SDK with RT-Thread system, mainly for initializing camera AE during quick boot. sysdrv:source:uboot: Added support for fastboot; added high baud rate DDR bin for serial firmware upgrades. sysdrv:source:kernel: Upgraded to version 5.10.160; increased NPU frequency for RV1106G3; added support for fastboot. Signed-off-by: luckfox-eng29 <eng29@luckfox.com>
56 lines
1.0 KiB
ArmAsm
56 lines
1.0 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
#
|
|
# arch/x86_64/setjmp.S
|
|
#
|
|
# setjmp/longjmp for the x86-64 architecture
|
|
#
|
|
|
|
#
|
|
# The jmp_buf is assumed to contain the following, in order:
|
|
# %rbx
|
|
# %rsp (post-return)
|
|
# %rbp
|
|
# %r12
|
|
# %r13
|
|
# %r14
|
|
# %r15
|
|
# <return address>
|
|
#
|
|
|
|
.text
|
|
.align 4
|
|
.globl kernel_setjmp
|
|
.type kernel_setjmp, @function
|
|
kernel_setjmp:
|
|
pop %rsi # Return address, and adjust the stack
|
|
xorl %eax,%eax # Return value
|
|
movq %rbx,(%rdi)
|
|
movq %rsp,8(%rdi) # Post-return %rsp!
|
|
push %rsi # Make the call/return stack happy
|
|
movq %rbp,16(%rdi)
|
|
movq %r12,24(%rdi)
|
|
movq %r13,32(%rdi)
|
|
movq %r14,40(%rdi)
|
|
movq %r15,48(%rdi)
|
|
movq %rsi,56(%rdi) # Return address
|
|
RET
|
|
|
|
.size kernel_setjmp,.-kernel_setjmp
|
|
|
|
.text
|
|
.align 4
|
|
.globl kernel_longjmp
|
|
.type kernel_longjmp, @function
|
|
kernel_longjmp:
|
|
movl %esi,%eax # Return value (int)
|
|
movq (%rdi),%rbx
|
|
movq 8(%rdi),%rsp
|
|
movq 16(%rdi),%rbp
|
|
movq 24(%rdi),%r12
|
|
movq 32(%rdi),%r13
|
|
movq 40(%rdi),%r14
|
|
movq 48(%rdi),%r15
|
|
jmp *56(%rdi)
|
|
|
|
.size kernel_longjmp,.-kernel_longjmp
|